From 5c3b7276abf0d01b53662f38db5b4d52377343ed Mon Sep 17 00:00:00 2001
From: Mark Weiman <mark.weiman@markzz.com>
Date: Sat, 2 Jan 2016 01:22:31 -0500
Subject: initial commit

Signed-off-by: Mark Weiman <mark.weiman@markzz.com>
---
 libindicator/.SRCINFO | 25 +++++++++++++++++
 libindicator/MKPKG    |  3 ++
 libindicator/PKGBUILD | 77 +++++++++++++++++++++++++++++++++++++++++++++++++++
 3 files changed, 105 insertions(+)
 create mode 100644 libindicator/.SRCINFO
 create mode 100644 libindicator/MKPKG
 create mode 100644 libindicator/PKGBUILD

(limited to 'libindicator')

diff --git a/libindicator/.SRCINFO b/libindicator/.SRCINFO
new file mode 100644
index 0000000..9fc8b54
--- /dev/null
+++ b/libindicator/.SRCINFO
@@ -0,0 +1,25 @@
+# Generated by mksrcinfo v8
+# Sat Dec 12 02:02:01 UTC 2015
+pkgbase = libindicator
+	pkgdesc = A set of symbols and convenience functions for Ayatana indicators
+	pkgver = 12.10.1
+	pkgrel = 6
+	url = https://launchpad.net/libindicator
+	arch = i686
+	arch = x86_64
+	license = GPL
+	makedepends = gtk2
+	makedepends = gtk3
+	source = https://launchpad.net/libindicator/12.10/12.10.1/+download/libindicator-12.10.1.tar.gz
+	sha256sums = b2d2e44c10313d5c9cd60db455d520f80b36dc39562df079a3f29495e8f9447f
+
+pkgname = libindicator-gtk2
+	depends = gtk2
+	provides = libindicator
+	conflicts = libindicator
+
+pkgname = libindicator-gtk3
+	depends = gtk3
+	provides = libindicator3
+	conflicts = libindicator3
+
diff --git a/libindicator/MKPKG b/libindicator/MKPKG
new file mode 100644
index 0000000..d0d02c0
--- /dev/null
+++ b/libindicator/MKPKG
@@ -0,0 +1,3 @@
+pkgname=('libindicator-gtk3')
+
+# vim: ts=2 sw=2 et:
diff --git a/libindicator/PKGBUILD b/libindicator/PKGBUILD
new file mode 100644
index 0000000..665c02b
--- /dev/null
+++ b/libindicator/PKGBUILD
@@ -0,0 +1,77 @@
+# Maintainer: Yurii Kolesnykov <yurikoles@gmail.com>
+# Contributor: Gustavo <sl1pkn07@gmail.com>
+# Contributor: Maxime Gauduin <alucryd@archlinux.org>
+# Contributor: Balló György <ballogyor+arch@gmail.com>
+
+pkgbase=libindicator
+pkgname=('libindicator-gtk2' 'libindicator-gtk3')
+pkgver=12.10.1
+pkgrel=6
+pkgdesc='A set of symbols and convenience functions for Ayatana indicators'
+arch=('i686' 'x86_64')
+url='https://launchpad.net/libindicator'
+license=('GPL')
+makedepends=('gtk2' 'gtk3')
+source=("https://launchpad.net/libindicator/${pkgver%.*}/${pkgver}/+download/libindicator-${pkgver}.tar.gz")
+sha256sums=('b2d2e44c10313d5c9cd60db455d520f80b36dc39562df079a3f29495e8f9447f')
+
+prepare() {
+  sed '/-Werror/s/$/ -Wno-deprecated-declarations/' -i libindicator-${pkgver}/libindicator/Makefile.{am,in}
+  sed 's/LIBINDICATOR_LIBS+="$LIBM"/LIBINDICATOR_LIBS+=" $LIBM"/g' -i libindicator-${pkgver}/configure
+  sed 's/LIBM="-lmw"/LIBM=" -lmw"/g' -i libindicator-${pkgver}/configure
+  sed 's/LIBM="-lm"/LIBM=" -lm"/g' -i libindicator-${pkgver}/configure
+  sed 's/LIBS="-lm  $LIBS"/LIBS=" -lm  $LIBS"/g' -i libindicator-${pkgver}/configure
+  sed 's/LIBS="-lmw  $LIBS"/LIBS=" -lmw  $LIBS"/g' -i libindicator-${pkgver}/configure
+
+
+  mkdir -p build-gtk{2,3}
+}
+
+build() {
+  cd build-gtk3
+
+  ../libindicator-${pkgver}/configure \
+    --prefix='/usr' \
+    --localstatedir='/var' \
+    --libexecdir='/usr/lib/libindicator' \
+    --sysconfdir='/etc' \
+    --disable-static \
+    --disable-tests
+  make
+
+  cd ../build-gtk2
+
+  ../libindicator-${pkgver}/configure \
+    --prefix='/usr' \
+    --localstatedir='/var' \
+    --libexecdir='/usr/lib/libindicator' \
+    --sysconfdir='/etc' \
+    --with-gtk='2' \
+    --disable-static \
+    --disable-tests
+  make
+}
+
+package_libindicator-gtk2() {
+  depends=('gtk2')
+  provides=('libindicator')
+  conflicts=('libindicator')
+
+  cd build-gtk2
+
+  make -j1 DESTDIR="${pkgdir}" install
+  rm -rf "${pkgdir}"/usr/share
+}
+
+package_libindicator-gtk3() {
+  depends=('gtk3')
+  provides=('libindicator3')
+  conflicts=('libindicator3')
+
+  cd build-gtk3
+
+  make -j1 DESTDIR="${pkgdir}" install
+  rm -rf "${pkgdir}"/usr/share
+}
+
+# vim: ts=2 sw=2 et:
\ No newline at end of file
-- 
cgit v1.3